@ECHO OFF
REM ****************************************************************************
REM
REM	                   TIC TAC TOE WSADOWO
REM                        -------------------
REM
REM                        autor: r.Q
REM                        licencja: GNU GPL
REM                        WWW: http://members.chello.pl/m.rataj
REM
REM	Ten plik obsluguje glowna czesc gry, czyli wywoluje modul
REM	odpowiedzialny za wyswietlanie planszy, pobiera numeru pola od
REM	gracza, wywoluje modul sprawdzajacy wynik gry, oraz zamienia graczy.
REM	Dodatkowym zadaniem tego modulu jest filtrowanie danych otrzymywanych
REM	od gracza. Zapobiega to nadpisywaniu pol, oraz zapobiega wpisywaniu
REM	wartosci bedacych poza zakresem.
REM
REM ****************************************************************************

CALL Pliki\wyswietl_plansze.bat
SET stanGry=0
:start
ECHO.
ECHO.
SET pole=0
:powrot
SET /P pole="Wpisz numer pola, w ktorym postawisz %aktualnyGracz%: "
SET /A temp="10-%pole%"
IF %temp% LSS 1 GOTO zly_numer_pola
IF %temp% GTR 9 GOTO zly_numer_pola
IF "!plansza[%temp%]!" EQU "O" GOTO pole_zajete
IF "!plansza[%temp%]!" EQU "X" GOTO pole_zajete
SET plansza[%temp%]=%aktualnyGracz%
CALL Pliki\wyswietl_plansze.bat
CALL Pliki\sprawdz.bat
IF "%stanGry%" EQU "koniec" GOTO koniec
IF "%aktualnyGracz%" EQU "O" (SET aktualnyGracz=X) ELSE (SET aktualnyGracz=O)
GOTO start

:zly_numer_pola
ECHO Nieprawidlowy numer pola.
GOTO powrot

:pole_zajete
ECHO Wybrane przez Ciebie pole jest juz zajete.
GOTO powrot

:koniec