@ECHO OFF
REM ***********************************************************************************
REM
REM 	Programik przydatny, gdy potrzebujemy wylistowac duzo plikow o podanych
REM	rozszerzeniach np. gdy chcemy zrobic listing swoich mp3, badz obrazow.
REM
REM	Skrypt pobrano ze strony: http://members.chello.pl/m.rataj
REM
REM ***********************************************************************************

IF EXIST wynik.txt DEL wynik.txt > NUL
IF "%1" == "/?" GOTO pomoc
IF "%1" == "" GOTO brak_argumentow

SETLOCAL
SET ile=0
:start
IF "%1" == "" GOTO wynik
SET sciezka=%~dp1
SET plik=*%~x1
FOR /R "%sciezka%" %%i IN (%plik%) DO ECHO %%~nxpi >> %TEMP%\lista && SET /A ile+=1
SHIFT
GOTO start

:pomoc
ECHO Program wyszukuje rekurencyjnie wszystkie pliki o podanym rozszerzeniu,
ECHO zaczynajac od katalogu podanego przez uzytkownika.
ECHO.
ECHO Skladnia:
ECHO.
ECHO listuj.bat [dysk:[katalog]]*.rozszerzenie_pliku
GOTO koniec

:brak_argumentow
ECHO Spodziewany argument. Wpisz 'listuj.bat /?' aby uzyskac pomoc.
GOTO koniec

:wynik
IF %ile% == 0 GOTO nie_znaleziono
SORT %TEMP%\lista /O wynik.txt > NUL
DEL %TEMP%\lista > NUL
ECHO ======================== >> wynik.txt
ECHO W sumie %ile% plikow. >> wynik.txt
ECHO Gotowe!
GOTO koniec

:nie_znaleziono
ECHO Nie znaleziono plikow.

:koniec
ENDLOCAL